ext::ai​

Enabling the Extension​

The AI extension can be enabled using the extension mechanism:

using extension ai;

Configuration​

The AI extension can be configured using configure session or configure current branch:

configure current branch
set ext::ai::Config::indexer_naptime := <duration>'PT30S';

select cfg::Config.extensions[is ext::ai::Config]{*};

configure current branch
reset ext::ai::Config::indexer_naptime;

UI​

The AI section of the UI can be accessed via the sidebar after the extension has been enabled in the schema. It provides ways to manage provider configurations and RAG prompts, as well as try out different settings in the playground.

Playground tab​

Provides an interactive environment for testing and configuring the built-in RAG.

Components:

• Message window: Displays conversation history between the user and the LLM.

• Model: Dropdown menu for selecting the text generation model.

• Prompt: Dropdown menu for selecting the RAG prompt template.

• Context Query: Input field for entering an EdgeQL expression returning a set of objects with AI indexes.

Prompts tab​

Provides ways to manage system prompts used in the built-in RAG.

Providers tab​

Enables management of API configurations for AI API providers.

Index​

The ext::ai::index creates a deferred semantic similarity index of an expression on a type.

module default {
  type Astronomy {
    content: str;
    deferred index ext::ai::index(embedding_model := 'text-embedding-3-small')
      on (.content);
  }
};

Parameters:

• embedding_model- The name of the model to use for embedding generation as a string.

• distance_function- The function to use for determining semantic similarity. Default: ext::ai::DistanceFunction.Cosine

• index_type- The type of index to create. Currently the only option is the default: ext::ai::IndexType.HNSW.

• index_parameters- A named tuple of additional index parameters:

  • m- The maximum number of edges of each node in the graph. Increasing can increase the accuracy of searches at the cost of index size. Default: 32

  • ef_construction- Dictates the depth and width of the search when building the index. Higher values can lead to better connections and more accurate results at the cost of time and resource usage when building the index. Default: 100

• dimensions: int64 (Optional) - Embedding dimensions

• truncate_to_max: bool (Default: False)

Functions​

module default {
  type Astronomy {
    topic: str;
    content: str;
    deferred index ext::ai::index(embedding_model := 'text-embedding-3-small')
      on (.topic ++ ' ' ++ .content);
  }
};

db> 
... 
... 
... 

insert Astronomy {
  topic := 'Mars',
  content := 'Skies on Mars are red.'
}

db> 
... 
... 
... 

insert Astronomy {
  topic := 'Earth',
  content := 'Skies on Earth are blue.'
}

db> 

select ext::ai::to_context(Astronomy);

{'Mars Skies on Mars are red.', 'Earth Skies on Earth are blue.'}

db> 
... 

with query := <array<float32>><json>$query
select ext::ai::search(Knowledge, query);

{
  (
    object := default::Knowledge {id: 9af0d0e8-0880-11ef-9b6b-4335855251c4},
    distance := 0.20410746335983276
  ),
  (
    object := default::Knowledge {id: eeacf638-07f6-11ef-b9e9-57078acfce39},
    distance := 0.7843298847773637
  ),
  (
    object := default::Knowledge {id: f70863c6-07f6-11ef-b9e9-3708318e69ee},
    distance := 0.8560434728860855
  ),
}

Scalar and Object Types​

configure current database
insert ext::ai::OpenAIProviderConfig {
  secret := 'sk-....',
};

insert ext::ai::ChatPrompt {
  name := 'test-prompt',
  messages := (
    insert ext::ai::ChatPromptMessage {
      participant_role := ext::ai::ChatParticipantRole.System,
      content := "Your message content"
    }
  )
};